*  JieJie Microelectronics H-Spice Model Library
*  Filename	: JMH65R190APLN_H v.20220923.txt
*  Product Name   : JMH65R190APLN (DFN8080-4L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Sep 23, 2022
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMH65R190APLN D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.17
RS S 3 1E-006
RG G 2 8.9
CGS 3 G 1.57E-9
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1.1E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 5.06582E-9 -1.914E-10 2.32806E-12 -1.23763E-14 3.21012E-17 -3.99743E-20 1.91295E-23

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                           tlevc = 0         
+acm = 4                       VMAX = 5.980848E6        ETA = 1.241069E-4      
+VTO = 3.469326           TOX = 5.979588E-12        NSUB = 2.664003E19   
+KP = 20.980698            U0 = 7.528208E-4            KAPPA = 4.34272E-2    
+GAMMA = 10              PHI = 0.949857                THETA = -4.54521E-6    
+BEX = -0.48                 TCV = 5.0E-3                    DELTA = 446.681452     

.model DCGD D
+CJO = 1.42E-9                 VJ = 6                        M = 1.8       

.model DSUB D
+IS = 7.493025E-13             N = 1.20079                   RS = 4.093437E-3    
+BV = 675                      tlev = 0                      tlevc = 0     
+tref = -1.835005              eg = 1.159268                 keg = 4.843649      
+gap1 = 9.509498E-5            gap2 = 8.366377               xti = -1.569806E-4    
+cta = 0                       ctp = 0                       tcv = 0     
+tm1 = 0                       tm2 = 0                       tpb = 0     
+tphp = 0                      trs = 0                       ttt1 = 0    
+ttt2 = 0                      xtitun = 3   

.model DLIM D
+IS = 1E-4        
.ends JMH65R190APLN

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************